Quite BASIC -- The Wall, break out action

Output

Canvas

BASIC Program

1000 REM The Wall
1010 REM Quite BASIC Game Project
1020 REM
2000 CLS
2100 PRINT " *** The Wall ***"
2110 PRINT
2120 PRINT  "     Left: 4"
2130 PRINT  "     Stop: 5"
2140 PRINT  "     Right: 6"
2200 REM The position of the left edge of
2210 REM  the paddle is in Z
2220 LET Z = 20
2222 REM D is a speed boost factor
2224 LET D = 1
2230 REM Draw the initial position of the paddle
2240 FOR I = Z TO Z + 6
2250 PLOT I, 0, "orange"
2260 NEXT I
2300 REM Draw the wall
2310 GOSUB 5000
2400 REM Initialze score (S) and extra balls (L)
2410 LET S = 0
2420 LET L = 2
3000 REM Main game loop
3010 IF ROUND(Y) <> 0 THEN PLOT X, Y, "gray"
3020 LET X = X + U
3030 LET Y = Y + V
3040 REM Round the X,Y position
3050 LET A = ROUND(X)
3060 LET B = ROUND(Y)
3070 REM Bounce off sides
3080 IF A <> -1 AND A <> 50 THEN GOTO 3130
3090 LET U = -U
3100 LET X = X + U
3110 LET A = ROUND(X)
3120 REM Bounce off top 
3130 IF B <> 50 THEN GOTO 3190
3140 LET V = -V
3150 LET Y = Y + V
3160 LET B = ROUND(Y)
3170 REM If at bottom bounce off paddle othewize
3180 REM check if hitting a brick
3190 IF B = 0 THEN GOSUB 4000 ELSE GOSUB 6000
3191 LET A = ROUND(X)
3192 LET B = ROUND(Y)
3200 IF B = 0 THEN PLOT A, B, "orange" ELSE PLOT A, B, "yellow"
3210 REM Paddle control
3220 REM First loop over the keyboard buffer
3230 LET C = UPPERCASE(GETCHAR())
3240 IF C = "" THEN GOTO 3290
3250 IF C = "4" THEN LET  W =-1
3260 IF C = "5"  THEN LET  W = 0
3270 IF C = "6"  THEN LET  W = 1
3280 GOTO 3230
3290 IF W <> -1 OR Z  = 0 THEN GOTO 3330
3300 PLOT Z + 6, 0, "gray" 
3310 LET Z = Z + W
3320 PLOT Z, 0, "orange"
3330 IF W  <> 1 OR Z = 43 THEN GOTO 3370
3340 PLOT Z, 0, "gray"
3350 LET Z = Z + W
3360 PLOT Z + 6, 0, "orange"
3370 REM pause before next iteration
3380 PAUSE 15 * (6 - LEVEL) / D
3390 GOTO 3000
4000 REM Subroutine for bouncing on the paddle 
4010 IF A < Z OR A > Z + 6 THEN GOTO 4500
4012 REM Reset speed boost to 1x
4014 LET D = 1
4016 LET V = -SGN(V)
4020 IF U < 0 THEN GOTO 4200
4030 IF A - Z = 6 THEN LET V = 0.6
4030 IF A - Z = 5 THEN LET V = 0.8
4050 IF A - Z = 0 THEN LET U = -U
4060 RETURN
4200 IF A - Z = 6 THEN LET U = -U
4220 IF A - Z = 1 THEN LET V = 0.8
4230 IF A - Z = 0 THEN LET V = 0.6
4240 RETURN
4500 LET L = L - 1
4502 REM Reset speed boost
4506 LET D = 1
4510 PLOT A, B, "yellow"
4520 GOSUB 7500
4530 IF L = -1 THEN GOTO 4600
4540 PAUSE 1000
4550 PLOT A, B, "gray"
4560 GOSUB 5500
4570 RETURN
4600 PRINT "GAME OVER"
4520 END
5000 REM Subroutine for drawing the bricks
5010 REM Number of bricks left is in N
5020 LET N = 0
5030 REM M determines how many red bricks to draw
5040 IF S < 5 THEN LET M = 10 ELSE IF S < 25 THEN LET M = 4 ELSE IF S < 42 THEN LET M = 3 ELSE LET M = 2 
5050 FOR I = 0 TO 4
5060 FOR J = 0 TO 3
5070 FOR X = 0 TO 8
5080 FOR Y = 0 TO 3
5090 IF (S = 0 AND J =1 AND I = 1) OR (J = 3 AND (I + 2) % M = 0) THEN LET C = "darkred" ELSE IF (X = 8 AND Y = 0) OR (X = 0 AND Y = 3) THEN LET C = "dimgray" ELSE IF X = 0 AND Y = 0 THEN LET C = "white" ELSE IF X = 0 OR Y = 0 THEN LET C = "lightgrey" ELSE IF X = 8 OR Y = 3 THEN LET C = "black" ELSE LET C = "dimgray"
5100 PLOT I*10 + X, 45 - J*5 - Y, C
5110 NEXT Y
5120 NEXT X
5130 IF C <> "darkred" THEN LET N = N + 1
5140 NEXT J
5150 NEXT I
5170 GOSUB 5500
5180 RETURN
5500 REM Reset the ball to the starting position
5510 LET X = 1
5520 LET Y = 25
5530 LET U = 1
5540 LET V = -1
5550 RETURN
6000 REM Subroutine for checking collision with a brick
6010 IF COLOR(A, B) = "gray" THEN RETURN
6020 IF COLOR(A - SGN(U),  B) = "gray" THEN GOTO 6070
6030 LET V = -V
6040 GOSUB 7000
6045 LET Y = Y + V
6050 RETURN
6070 IF COLOR(A, B - SGN(V)) = "gray" THEN GOTO 6110
6080 LET U = -U 
6090 GOSUB 7000
6095 LET X = X + U
6100 RETURN
6110 LET V = -V
6115 LET Y = Y + V
6120 LET U = -U 
6125 LET X = X + U
6130 GOSUB 7000
6140 RETURN
7000 REM Subroutine for removing a brick
7010 IF COLOR(A, B) <> "darkred" THEN GOTO 7030
7011 REM Boost speed 3x
7012 LET D = 3
7013 REM Flash the brick
7014 LET P = FLOOR(A / 10) * 10
7015 LET Q = 50 - FLOOR((50-B) / 5) * 5
7016 FOR I = P TO P + 8
7017 FOR J = Q TO Q - 3 STEP -1
7018 PLOT I, J, "red"
7019 NEXT J
7020 NEXT I
7921 PAUSE 25 
7122 FOR I = P TO P + 8
7123 FOR J = Q TO Q - 3 STEP -1
7124 PLOT I, J, "darkred"
7125 NEXT J
7126 NEXT I
7027 RETURN
7030 LET P = FLOOR(A / 10) * 10
7040 LET Q = 50 - FLOOR((50-B) / 5) * 5
7050 FOR I = P TO P + 8
7060 FOR J = Q TO Q - 3 STEP -1
7070 IF RAND(1) > 0.7 THEN PLOT I, J, "orange" ELSE PLOT I, J, "gray"
7080 NEXT J
7090 NEXT I
7995 PAUSE 25 
7100 FOR I = P TO P + 8
7110 FOR J = Q TO Q - 3 STEP -1
7120 PLOT I, J, "gray"
7130 NEXT J
7140 NEXT I
7150 LET S = S + 1
7160 GOSUB 7500
7180 LET N = N - 1
7190 IF N = 0 THEN GOSUB 5000
7200 RETURN 
7500 REM Subroutine for updating the status line
7510 CLT
7520 PRINT "The Wall - Score:" + S;
7530 IF L <> -1 THEN PRINT " - Balls:" + L ELSE PRINT
7540 RETURN

Controls

Line:

Expr:

Value:

>QUITE BASIC
>

fun and learning for smart kids

nostalgia for the rest of us

>QUITE BASIC>

fun and learning for smart kids

nostalgia for the rest of us

>QUITE BASIC
>